##############################################################
#                                                            #
#                      MADE BY TSTOM0                        #
#                                                            #
##############################################################
 
## Easily allow staff on your server to reset an interact script for particular players ingame.
## Simple add the command below, an example would be on the chat trigger of "reset".
 
## ----------------------- FEATURES ----------------------- ##
##
##  * Supports permissions, simply add the permission node "denizen.scripts.resetsteps".
##  * Supports multiple interact scripts and multiple players.
##
## -------------------------------------------------------- ##
 
## COMMAND - RUN SCRIPT:RESETSTEPS DEF:<AmountOfInteractScriptsHere>|<FirstInteractScript>|<NextInteractScript>
## EXAMPLE - RUN SCRIPT:RESETSTEPS DEF:3|firstscript|secondscript|thirdscript
##
## INGAME - Enter names like "tstom0,Igkn,randomplayer"

ResetStepsChat:
  Type: World
  Debug: False
  Events:
    on player chats:
      - IF <player.has_flag[ResetSteps]> {
        - IF <context.message> == "cancel" || <context.message> == "exit" {
          - FLAG player "ResetSteps:!"
          - NARRATE "<red>Your chat capabilities have been restored."
          }
          ELSE {
          - NARRATE "<gold> ===================================================="
          - FOREACH "<context.message.split[,].as_list>" {
            - DEFINE playername "%value%"
            - IF <p@%playername%.has_played_before> {
              - FOREACH <player.flag[ResetSteps].as_list> {
                - DEFINE scriptname "%value%"
                - ZAP STEP:1 SCRIPT:%scriptname% PLAYER:p@%playername%
                }
              - NARRATE "<&d> - <green><aqua>%playername% <green>has had their progress reset!"
              }
              ELSE {
              - NARRATE "<&d> - <aqua>%playername% <yellow>is not a valid player!"
              }
            }
          - NARRATE "<red> Type <&d>cancel <red>or <&d>exit <red>to return to normal."
          - NARRATE "<gold> ===================================================="
          }
        - DETERMINE cancelled
        }

ResetSteps:
  Type: Task
  Script:
    - IF <player.has_permission[denizen.scripts.resetsteps]> != "true" {
      - NARRATE "<red>Insufficient Permissions!"
      - QUEUE clear
      }
    - DEFINE scriptamount "%1%"
    - DEFINE interactScript "2"
    - REPEAT %scriptamount% {
      - DEFINE value "<def[%interactScript%]>"
      - FLAG player "ResetSteps:->:%value%"
      - DEFINE interactScript "<def[interactScript].add[1].as_int>"
      }
    - ^NARRATE "<red>Please enter the players name."
    - ^NARRATE "<red>You will not be able to chat during this time."
    - ^NARRATE "<red>Type <&d>cancel <red>or <&d>exit <red>to return to normal."